# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit flag-o-matic systemd savedconfig toolchain-funcs

DESCRIPTION="IEEE 802.11 wireless LAN Host AP daemon"
HOMEPAGE="https://w1.fi/ https://w1.fi/cgit/hostap/"
S="${S}/${PN}"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://w1.fi/hostap.git"
else
	if [[ ${PV} =~ ^.*_p[0-9]{8}$ ]]; then
		SRC_URI+=" https://dev.gentoo.org/~andrey_utkin/distfiles/${P}.tar.xz"
	else
		SRC_URI+=" https://w1.fi/releases/${P}.tar.gz"
	fi

	# Never stabilize snapshot ebuilds please
	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~x86"
fi

LICENSE="BSD"
SLOT="0"
IUSE="internal-tls netlink selinux sqlite +suiteb +wps"

DEPEND="
	internal-tls? ( dev-libs/libtommath )
	!internal-tls? ( dev-libs/openssl:0=[-bindist(-)] )
	kernel_linux? (
		net-wireless/wireless-regdb
		>=dev-libs/libnl-3.2:3
	)
	netlink? ( net-libs/libnfnetlink )
	sqlite? ( dev-db/sqlite:3 )
"
RDEPEND="
	${DEPEND}
	selinux? ( sec-policy/selinux-hostapd )
"
BDEPEND="virtual/pkgconfig"

pkg_pretend() {
	if use internal-tls; then
		ewarn "internal-tls implementation is experimental and provides fewer features"
	fi
}

src_unpack() {
	# Override default one because we need the SRC_URI ones even in case of 9999 ebuilds
	default

	if [[ ${PV} == 9999 ]] ; then
		git-r3_src_unpack
	fi
}

src_prepare() {
	# Allow users to apply patches to src/drivers for example,
	# i.e. anything outside ${S}/${PN}
	pushd ../ >/dev/null || die
	default
	popd >/dev/null || die

	sed -i -e "s:/etc/hostapd:/etc/hostapd/hostapd:g" \
		"${S}/hostapd.conf" || die
}

src_configure() {
	local CONFIG="${S}"/.config

	restore_config "${CONFIG}"
	if [[ -f "${CONFIG}" ]]; then
		default
		return 0
	fi

	cat > "${CONFIG}" <<-EOF || die
		CC = $(tc-getCC)

		# EAP authentication methods
		CONFIG_EAP=y
		CONFIG_ERP=y
		CONFIG_EAP_MD5=y
		CONFIG_EAP_IKEV2=y
		CONFIG_EAP_TNC=y
		CONFIG_EAP_GTC=y
		CONFIG_EAP_SIM=y
		CONFIG_EAP_AKA=y
		CONFIG_EAP_AKA_PRIME=y
		CONFIG_EAP_EKE=y
		CONFIG_EAP_PAX=y
		CONFIG_EAP_PSK=y
		CONFIG_EAP_SAKE=y
		CONFIG_EAP_GPSK=y
		CONFIG_EAP_GPSK_SHA256=y

		# drivers
		CONFIG_DRIVER_WIRED=y
		CONFIG_DRIVER_NONE=y
		CONFIG_DRIVER_NL80211=y

		CONFIG_ELOOP_EPOLL=y

		# misc
		CONFIG_DEBUG_FILE=y
		CONFIG_PKCS12=y
		CONFIG_RADIUS_SERVER=y
		CONFIG_IEEE80211R=y
		CONFIG_IEEE80211AC=y
		CONFIG_IEEE80211AX=y
		CONFIG_IEEE80211BE=y
		CONFIG_OCV=y
		CONFIG_RSN_PREAUTH=y
		CONFIG_IPV6=y
		CONFIG_INTERWORKING=y
		CONFIG_FULL_DYNAMIC_VLAN=y
		CONFIG_HS20=y
		CONFIG_WNM=y
		CONFIG_FST=y
		CONFIG_FST_TEST=y
		CONFIG_ACS=y
	EOF

	if use suiteb; then
		cat >> "${CONFIG}" <<-EOF || die
			CONFIG_SUITEB=y
			CONFIG_SUITEB192=y
		EOF
	fi

	if use internal-tls; then
		echo "CONFIG_TLS=internal" >> "${CONFIG}" || die
	else
		# SSL authentication methods
		cat >> "${CONFIG}" <<-EOF || die
			CONFIG_DPP=y
			CONFIG_EAP_FAST=y
			CONFIG_EAP_MSCHAPV2=y
			CONFIG_EAP_PEAP=y
			CONFIG_EAP_PWD=y
			CONFIG_EAP_TLS=y
			CONFIG_EAP_TTLS=y
			CONFIG_OWE=y
			CONFIG_SAE=y
			CONFIG_TLSV11=y
			CONFIG_TLSV12=y
		EOF
	fi

	if use wps; then
		cat >> "${CONFIG}" <<-EOF || die
			CONFIG_WPS=y
			CONFIG_WPS_UPNP=y
			CONFIG_WPS_NFC=y
		EOF
	fi

	if use netlink; then
		echo "CONFIG_VLAN_NETLINK=y" >> "${CONFIG}" || die
	fi

	if use sqlite; then
		echo "CONFIG_SQLITE=y" >> "${CONFIG}" || die
	fi

	if use kernel_linux; then
		echo "CONFIG_LIBNL32=y" >> "${CONFIG}" || die
		append-cflags "$($(tc-getPKG_CONFIG) --cflags libnl-3.0)"
	fi

	# TODO: Add support for BSD drivers

	default
}

src_compile() {
	emake V=1

	if ! use internal-tls; then
		emake V=1 nt_password_hash
		emake V=1 hlr_auc_gw
	fi
}

src_install() {
	insinto /etc/${PN}
	doins ${PN}.{conf,accept,deny,eap_user,radius_clients,sim_db,wpa_psk}

	fperms -R 600 /etc/${PN}

	dosbin ${PN}
	dobin ${PN}_cli

	if ! use internal-tls; then
		dobin nt_password_hash hlr_auc_gw
	fi

	newinitd "${FILESDIR}/${PN}-init.d" ${PN}
	newconfd "${FILESDIR}/${PN}-conf.d" ${PN}
	systemd_dounit "${FILESDIR}/${PN}.service"

	doman ${PN}{.8,_cli.1}

	dodoc ChangeLog README
	use wps && dodoc README-WPS

	docinto examples
	dodoc wired.conf

	insinto /etc/log.d/conf/services/
	doins logwatch/${PN}.conf

	exeinto /etc/log.d/scripts/services/
	doexe logwatch/${PN}

	save_config .config
}

pkg_postinst() {
	einfo
	einfo "If you are running OpenRC you need to follow this instructions:"
	einfo "In order to use ${PN} you need to set up your wireless card"
	einfo "for master mode in /etc/conf.d/net and then start"
	einfo "/etc/init.d/${PN}."
	einfo
	einfo "Example configuration:"
	einfo
	einfo "config_wlan0=( \"192.168.1.1/24\" )"
	einfo "channel_wlan0=\"6\""
	einfo "essid_wlan0=\"test\""
	einfo "mode_wlan0=\"master\""
	einfo

	#if [[ -e "${KV_DIR}"/net/mac80211 ]]; then
	#	einfo "This package now compiles against the headers installed by"
	#	einfo "the kernel source for the mac80211 driver. You should "
	#	einfo "re-emerge ${PN} after upgrading your kernel source."
	#fi

	if use wps; then
		einfo "You have enabled Wi-Fi Protected Setup support, please"
		einfo "read the README-WPS file in /usr/share/doc/${PF}"
		einfo "for info on how to use WPS"
	fi
}